[gentoo-commits] repo/gentoo:master commit in: dev-ruby/io-event/

["Sam James" <sam@gentoo.org>]

commit:     be34a2ecb62c1757d5f31d3534f8c897e6719a98
Author:     Gabi Falk <gabifalk <AT> gmx <DOT> com>
AuthorDate: Sat Oct 12 16:40:00 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Dec  1 12:37:02 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=be34a2ec

dev-ruby/io-event: 1.5.1: apply upstream commit to fix the testsuite

Link: https://github.com/socketry/io-event/commit/c2ffc28e97a08534e003eaf25abfa35279274263
Closes: https://bugs.gentoo.org/941411
Signed-off-by: Gabi Falk <gabifalk <AT> gmx.com>
Closes: https://github.com/gentoo/gentoo/pull/38956
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-ruby/io-event/io-event-1.5.1-r1.ebuild | 40 ++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

diff --git a/dev-ruby/io-event/io-event-1.5.1-r1.ebuild b/dev-ruby/io-event/io-event-1.5.1-r1.ebuild
new file mode 100644
index 000000000000..49f3e0ca5c6d
--- /dev/null
+++ b/dev-ruby/io-event/io-event-1.5.1-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/extconf.rb)
+RUBY_FAKEGEM_EXTRADOC="readme.md"
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+RUBY_FAKEGEM_RECIPE_TEST="sus"
+
+inherit ruby-fakegem
+
+DESCRIPTION="An event loop"
+HOMEPAGE="https://github.com/socketry/io-event"
+SRC_URI="https://github.com/socketry/io-event/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+io-uring"
+
+RDEPEND="io-uring? ( sys-libs/liburing:= )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.6.5-update-test-hooks.patch
+)
+
+all_ruby_prepare() {
+	sed -i -E 's/require_relative "(.+)"/require File.expand_path("\1")/g' "${RUBY_FAKEGEM_GEMSPEC}" || die
+
+	# Avoid dependency on unpackaged covered package
+	rm -f config/sus.rb || die
+
+	if ! use io-uring ; then
+		sed -i -e "s:have_library('uring'):have_library('idonotexist_uring'):" ext/extconf.rb || die
+	fi
+}