[gentoo-commits] repo/gentoo:master commit in: app-text/paper-clip/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     e62c76d946054c03f1c22a9c9c4791f23fcea9db
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon May  6 16:25:40 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon May  6 18:00:13 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e62c76d9

app-text/paper-clip: bump to 5.5

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-text/paper-clip/Manifest              |  1 +
 app-text/paper-clip/paper-clip-5.5.ebuild | 72 +++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/app-text/paper-clip/Manifest b/app-text/paper-clip/Manifest
index 71dac68e6efc..267a62cddd78 100644
--- a/app-text/paper-clip/Manifest
+++ b/app-text/paper-clip/Manifest
@@ -1 +1,2 @@
 DIST paper-clip-5.0.tar.gz 182085 BLAKE2B 07c397218417a5bc87e95aec577465b3f109de4c081bf0f208e0213b71ea7a8f9bac415221a04c8729add7d82adf98c859b60b1b0bd9dbef2db021ee80ff9296 SHA512 2757768414b2177511b61c0a9bde9710b67128a446640bb3ae3bba22a9b30a2b8b036ee32806dc6e4662ffc3d06254006b89e6b63cdc11950b38257e9ea46023
+DIST paper-clip-5.5.tar.gz 183365 BLAKE2B 74b2b893ad7f421eeeb7e6c5bd3921b20b379cebcdb86371a262455fe95a67c0fdddc894b5ecb3da9d7c612a6e9e7ac91ba4d98cc4e2cfb994de388f9f0f8a45 SHA512 880ed9ee81788e1d1f50d0bf5c119ebf2f45a939432f44e363ce0513217a74af7f9fd012f110fc3a38db392341a3529b8785f0130a4bf0fe83f6dbe12d663b19

diff --git a/app-text/paper-clip/paper-clip-5.5.ebuild b/app-text/paper-clip/paper-clip-5.5.ebuild
new file mode 100644
index 000000000000..8a822daeac38
--- /dev/null
+++ b/app-text/paper-clip/paper-clip-5.5.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+APP_PN="Paper-Clip"
+
+inherit gnome2-utils meson vala xdg
+
+DESCRIPTION="Edit the title, author, keywords and more details of PDF documents"
+HOMEPAGE="https://github.com/Diego-Ivan/Paper-Clip/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/Diego-Ivan/${APP_PN}.git"
+else
+	SRC_URI="https://github.com/Diego-Ivan/${APP_PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${APP_PN}-${PV}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+RESTRICT="test"                      # Only validations, the appdata one fails.
+
+RDEPEND="
+	>=gui-libs/gtk-4.12.5:4
+	>=gui-libs/libadwaita-1.4.2:1[introspection,vala]
+	app-text/poppler:=[cairo,introspection]
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	dev-libs/libportal:=[gtk,introspection,vala]
+	media-libs/exempi
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+"
+
+DOCS=( README.md )
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_install() {
+	meson_src_install
+	einstalldocs
+
+	# Symlink "pdf-metadata-editor" (old name?) to "${PN}".
+	dosym -r /usr/bin/pdf-metadata-editor "/usr/bin/${PN}"
+
+	mv "${ED}/usr/share/appdata" "${ED}/usr/share/metainfo" || die
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}