[gentoo-commits] repo/gentoo:master commit in: x11-terms/terminator/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     c8c9a6cf932606099f4ed39ec26e244b2da66b0e
Author:     Alexey Sokolov <alexey+gentoo <AT> asokolov <DOT> org>
AuthorDate: Sun May 22 22:54:44 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Mon May 23 21:15:22 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c8c9a6cf

x11-terms/terminator: support py3.10, use pep517

Closes: https://bugs.gentoo.org/846359
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Alexey Sokolov <alexey+gentoo <AT> asokolov.org>
Closes: https://github.com/gentoo/gentoo/pull/25600
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 x11-terms/terminator/terminator-2.1.1-r1.ebuild | 66 +++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

diff --git a/x11-terms/terminator/terminator-2.1.1-r1.ebuild b/x11-terms/terminator/terminator-2.1.1-r1.ebuild
new file mode 100644
index 000000000000..19885249a992
--- /dev/null
+++ b/x11-terms/terminator/terminator-2.1.1-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 optfeature verify-sig virtualx xdg
+
+DESCRIPTION="Multiple GNOME terminals in one window"
+HOMEPAGE="https://github.com/gnome-terminator/terminator"
+SRC_URI="
+	https://github.com/gnome-terminator/terminator/releases/download/v${PV}/${P}.tar.gz
+	verify-sig? ( https://github.com/gnome-terminator/terminator/releases/download/v${PV}/${P}.tar.gz.asc )
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-python/configobj[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	gnome-base/gsettings-desktop-schemas[introspection]
+	x11-libs/gtk+:3
+	x11-libs/vte:2.91[introspection]
+"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	test? (
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		x11-libs/libnotify[introspection]
+	)
+	verify-sig? ( sec-keys/openpgp-keys-terminator )
+"
+distutils_enable_tests pytest
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/terminator.asc
+
+PATCHES=(
+	"${FILESDIR}"/terminator-1.91-without-icon-cache.patch
+	"${FILESDIR}"/terminator-1.91-desktop.patch
+)
+
+src_prepare() {
+	xdg_environment_reset
+	sed -i -e '/pytest-runner/d' setup.py || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "D-Bus" dev-python/dbus-python
+	optfeature "desktop notifications" "x11-libs/libnotify[introspection]"
+	optfeature "global keyboard shortcuts" "dev-libs/keybinder:3[introspection]"
+}