[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

["Sam James" <sam@gentoo.org>]

commit:     1784524693d4a1f85f46c3f280eb320ef66bb8a3
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  2 03:51:46 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Oct  2 03:51:46 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=17845246

sys-kernel/gentoo-kernel-bin: add 5.14.9-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.14.9-r1.ebuild             | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index c128c8d8be0..339de659fe4 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -37,6 +37,7 @@ DIST gentoo-kernel-5.14.8-1.amd64.xpak 68070862 BLAKE2B 6f98d2eb2affd7705b5886f2
 DIST gentoo-kernel-5.14.8-1.arm64.xpak 63311629 BLAKE2B 0bdc32d597f413bc2b30e704a599c0edf55ce5437772ed886da5a6787ddcce5c6eebc699860df41536a8449f5442f56ca8ff1d10a5bd3f142c9f1092fb6c02cf SHA512 2e27ea733f68d49afe2fe5bc654e9ce4125ad87bad4a98936473c1e4d9c8b59374c226c4cc397f52463371b41cacc59d274bda421842a080f0804739b8c72fbc
 DIST gentoo-kernel-5.14.8-1.x86.xpak 59162488 BLAKE2B 12f31c41617eacce67f9ee960c9959fc7e19f074dd31bfa080eacde89ba6215136dee0a00f7c0127ab0f8fcd4896c24a132333ec64845c0756ba89c6d47a7e44 SHA512 6e230c100fb83e144ab91e02697800286ad331ea1a3fedb370dc1c3615c2dee0ac47a9438b97dc38c9fc6cdc44d54fe18e721fe8cb47e9f5552dd9edd154d61a
 DIST gentoo-kernel-5.14.9-1.amd64.xpak 68066846 BLAKE2B da508a4e8e96dcc0ea331f9c798808e4b0047cce6342994b5a2248d5becf1fd010e0ee8d7dd3427e4ead92359b9c1b92e2085d91fe08b5ee6c73f9622ec58bb2 SHA512 e5a90c9ed4a3192e4ecf283bf76efa1a5e39af1f20eb18e9494dcfb8d2ef88ab23e4bec53ec81c664c0cbd47a22eb8d6907b21e970ec7b41e4ed97b4cf3b2c83
+DIST gentoo-kernel-5.14.9-1.arm64.xpak 63374537 BLAKE2B c33b1233a10ad02d60985f91ebcc2364195bf966a3b0a5fea9bf10f4f2db24c86d047f845de61a8fc41ef22cb1451cb0a14e4f7e62f51640df41ce2d058a1f7b SHA512 953539d6c24d4ef607b2d1f00b341fe0e1d0698f5075ebdae63d13d0b6d6820e45054589875d7af6d48160a952b780703867a3a33c69c082de6ecd2fda21fb20
 DIST gentoo-kernel-5.14.9-1.x86.xpak 59163747 BLAKE2B 23feb5d1d74c8ae1e3f4a66b215e887e4bfe700d80bbe8c75cabac9632808193e8a29f7c43baa2376279eb3b4fc9be530528731f02ba94778fd2e087e216d9ee SHA512 90492421abd0ed5a026c8cacbf64050e2ad18b7305ef96131964a6203e32d278ef7f1392ad76dab12ff3057c17046d44b371c567d8ef4ea18e0c2678c9208414
 DIST gentoo-kernel-5.4.148-1.amd64.xpak 61364378 BLAKE2B 2d5a665f5ccee0de5abc78d593b8bc6f1da0fa6fa9573ee9c0a65efaae9629ac3ea0b26a4b83e6abb23eee5fcb842fd67a395af35fb5476529b30dc0739d7944 SHA512 277064e06bdf25fc67f0894ab1d8116f23c71488b92a1751833c6aff684c7f2d28e2116e31d40878caa3f741fe9fe61f1f0c3cfaca4677298d2851b22afdf1ff
 DIST gentoo-kernel-5.4.148-1.arm64-r1.xpak 57998682 BLAKE2B a27bee25e2e6b2c0fea38cb5bee1ce433c6dbf10468b374ffb237a15403a4acb7feb0729526d337c5c9b1a85c4afc63716fa3c4b5fbe32c03ddb6966765f8946 SHA512 c72a4d8bc4bca7cf9ad5b594d7cadff11f9a4ec7181c0dbdce14919a1af50c1a901dd69b1a5d3f35abe51f9ca82f729f352ac8873d0b0f225e4bdd45a213b350

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.9-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.9-r1.ebuild
new file mode 100644
index 00000000000..c4534b7e4c4
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.9-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}