[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

["Sam James" <sam@gentoo.org>]

commit:     a6aebd61e4a95037f6332ff9e99101c3e8a1d00d
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Aug 27 20:21:43 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Aug 27 20:22:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a6aebd61

sys-kernel/gentoo-kernel-bin: bump to 5.10.61-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.61-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index db171016a16..e223be8d3dc 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -32,6 +32,7 @@ DIST gentoo-kernel-5.10.60-1.amd64.xpak 65504358 BLAKE2B 233766cf8fd62c2b70cf257
 DIST gentoo-kernel-5.10.60-1.arm64.xpak 61199661 BLAKE2B 1d004eae20fe67cdde4612d56e648cdd22975a1b5b418c0e1b80a1f9235f1b0917f4af6f8946da793dbf9fa20a42033ab397ece19308bea10b0ce5c550b45409 SHA512 649886a2117b8318dd03ce8a85905abb79cabf888ee5441da5a56d22354cbcda5be8343ada6335310dfd6192d5f3e145220aaaa52d3efd6b943151c0a3692f5f
 DIST gentoo-kernel-5.10.60-1.x86.xpak 57229580 BLAKE2B 90b7d12883271c0ac49cfff5ece81fde229c2f9f5c27c21d19c4c97132dd091bb798d75332c72491178655d8350e30addf868df71562bbaf645af5705d49daeb SHA512 043d1a0c5cefc49188a444b2ccc85decae53a318ee759449af4b30922a46329d57e1fd45f40b5c74b74f08e0cc5edc2835ba8291be460dea9699a998b9e1a6ac
 DIST gentoo-kernel-5.10.61-1.amd64.xpak 65508440 BLAKE2B 01f5355fd55446af79a237078b51a6899031327816fd59141d4ad947f1905e90c9fb7e74fac640e57d7f89c90bf3743fe76c82deb09d6a6fb4cbabbd3dbbd486 SHA512 8ece6b9caafc87297c29b92b4c2a6225dea5fc040072263ff17c89c64205d8ce2bd0e940f41ecb46d4cc1cf335688063ebacc71db8562925f9b741c6d402fb7b
+DIST gentoo-kernel-5.10.61-1.arm64.xpak 61237660 BLAKE2B 38ff2da5eeb647c94a2ae65dc13151ab4518add38194e2d536d894a5ef4781b2519face8a041b5c054a99aa859c8b6669b41894a29f5ed509ac6525b3d4ca129 SHA512 530fc813a38d38e259a67a666ec02c933deb18e143c58e44fe400e15a74390ab3d25b2a1724a44ad0246a49d1b578fab5c3393f4dc112b6cf0ccc38ecca5be86
 DIST gentoo-kernel-5.10.61-1.x86.xpak 57244029 BLAKE2B aa8acb2cace6c0345f982fea374cecf7e9de1897f6dfd73fd50d41b649e62fc0ca044028e72483daf63440221c1d502e0c4f65486376dda8ce6f23f973bbcf22 SHA512 2e73afac593acb951ff1bd9048b15ace23f57e9b958fb134a484f2922d02d4e4d8a72f0f5cd8507873e324e1830cbb3b1a97ee4fbecd9a4704f96f5c54c0de2d
 DIST gentoo-kernel-5.12.19-1.amd64.xpak 66346655 BLAKE2B a03cbcdcd1a90d48d7e11e988d03efa43980f4d5d8af4b74e4c81f195faa01803af45fb38f7dc1f5af7e9b5338a53bc6f34837c37f7e853c088ec6c1dc084e44 SHA512 3d7f78c488ecee2532f8a8ad61e3aa0f5e238e4cd520d29288715a3dc5c488670d7378f3dc5bc110252dff10108dfbda27a54722c6b044151999428d002b34e1
 DIST gentoo-kernel-5.12.19-1.arm64.xpak 60043529 BLAKE2B 8746081847a39e1847b8e9f35fcd68565370b116d6418edf803c4cdca9d750ac8ada58c4a7fd377480a1c75b3c805864d419c02ee21675bc77ac195731385a18 SHA512 d1a8a9210a1ab3d3c1894be1fe524e64b859b0a02763feacfed1a24655540ade6c28af751b23e924fcc04fb9abd56e84c43d634ad80bbb4d5de79ed533b5ea50

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.61-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.61-r1.ebuild
new file mode 100644
index 00000000000..9f8ae493e21
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.61-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}