[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

["Sam James" <sam@gentoo.org>]

commit:     a24b0d1ab2e105148883ec24d1fd7d6de33e12ab
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 10 00:53:30 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Apr 10 00:53:30 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a24b0d1a

sys-kernel/gentoo-kernel-bin: bump to 5.4.110 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.110-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 8fc6d0ccb98..975c3a20dc8 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -78,6 +78,7 @@ DIST gentoo-kernel-5.4.109-1.amd64.xpak 61197533 BLAKE2B d192b84c8e00a992256d44b
 DIST gentoo-kernel-5.4.109-1.arm64.xpak 56430663 BLAKE2B 6079b762ab5cdeb0c745a1a030e4a3af36883588c88dcb8c8cd811aa47d7cbaebc573b152f01fed451dbbfda1ec89ed400270e6fda4e3e1df1aec497b3f7815a SHA512 2d29230577255473618d698363af8c7ef8dd9dd3dcaeaec8fc8802e453838d2c1685e001a6ceb784f6c6ab77fb2b991366e213fec9c45b5763a3a5f57674cef7
 DIST gentoo-kernel-5.4.109-1.x86.xpak 53002823 BLAKE2B eb9548ce9e285fa665e2adc01f33198b9f2b2ae1ea21ddbaf10c9a92664ac6bb12da1c7c6c1923e2efe4746879d3ee27b75f560a69d958465fcea03ebb4f3a7d SHA512 f3848ac5f9ba9e04af65e1b1888e7a2b9836dfeb8ca3f5a692146f524f8e8d87d7b6766183879c879004d8505f013553d13885ffcf97724ba6f1df49c724af3f
 DIST gentoo-kernel-5.4.110-1.amd64.xpak 61394099 BLAKE2B 5907a7f6ffa336e6044c47b1f22b060307759c11e1e10cd28bd7bb68859525fb0480795aa46d476bdf654b412d2b311c642455b935cbf8b190f07b6e6c9b9545 SHA512 3bc0a82f09fd722cfdc4803a8f72289bfa7e528725ebf34c39831c61a2797c8947af5fdac3aecf9855c2ad4d51ef55eb9387e1ac0a3d85ada2775c103673a2c7
+DIST gentoo-kernel-5.4.110-1.arm64.xpak 56429255 BLAKE2B 714380f1f515bc30796d7b19c21b5565664c0ec1db016f10371d2d4e03ebd3d6fdef0d6891b694bda5032f99e98805960e19012723de1168f9cf41b44022bee2 SHA512 4ab7b907d9dec2147390a13052b7579fcbf9473cebff5d3bca25934de8b12c04935f9d2a62a3beae136e3897dc7702c7dd00aba6d60cd662d940b07a68dcd3af
 DIST gentoo-kernel-5.4.110-1.x86.xpak 53179555 BLAKE2B 39ed8da5d56906c750502a33062aecd67d0561f69df1efbbefe55ea960167baad1ed70a8b9c27a0158fad8fc7378f8af1bc86784c3b2fdbe5661fda3cee0a853 SHA512 f0aa83b79be333191a7e161533604e9fde45e62cf32df535059883b0daf101e54ecdaf93ee1b278228ce8ccd9228b750d05206223ecd922383688158c847bc2d
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.11.tar.xz 117619104 BLAKE2B 81300c27bd5476387a83123aaeb4163c73eb61e9245806c23660cb5e6a4fa88ffc9def027031335fa0270fc4080506cd415990014364e3a98b9d2e8c58a29524 SHA512 a567ec133018bb5ec00c60281479b466c26e02137a93a9c690e83997947df02b6fd94e76e8df748f6d70ceb58a19bacc3b1467de10b7a1fad2763db32b3f1330

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.110-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.110-r1.ebuild
new file mode 100644
index 00000000000..b63276300c5
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.110-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}