[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

["Sam James" <sam@gentoo.org>]

commit:     c12a43b3ac53ee209286c1a7fd8a03fe5587bf8d
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 21 10:45:15 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Mar 21 10:46:38 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c12a43b3

sys-kernel/gentoo-kernel-bin: bump to 5.4.106 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.106-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 86342aa55b4..c0cbf462471 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -92,6 +92,7 @@ DIST gentoo-kernel-5.4.105-1.x86.xpak 52996400 BLAKE2B 13dd3bfb78f48560ca8716f0b
 DIST gentoo-kernel-5.4.105-2.arm64.xpak 56452913 BLAKE2B 40668123ed047a7a5e5d8489062f3d02b8b3b59a9baa668788a356624afe962e6424acf7f55739fdae7ec13b8ad0be8f85a63e7c2599ce9290cb80c822b9ee31 SHA512 e7c717d8ad8999ccdf25b14b2f8e94be91f8012cf97f0f5379f31dbebcf2c548e05ea6e39e871c3309ec4206bd268bec363fa515722ad1a584b552424959d268
 DIST gentoo-kernel-5.4.106-1.amd64.xpak 61146719 BLAKE2B eb8ae4d9042e3ad9e69a5fae488763964c257e7a78f3b08b8d7b8a313bcdb48e975c4116c9b8e68be42c45351e7035e6ab892e155600a0ac3560ae54f84f6170 SHA512 b823ec881b83f42e54e2b393ed5060d84a7dcf9b7ed3967dc43124a88548f834c3eab56a679b8277d3427e9e05601ea3b06e218fc9923b5aa39bac09774194e1
 DIST gentoo-kernel-5.4.106-1.x86.xpak 52989825 BLAKE2B fbcb31f68a1a03d1395e66c5491e35006ef642090d1c4b14892eb43d56b818663e40666ead8dcda0c0b7814739b41e3c4fa27c3d9a7ddee05a652f3560a1e3a2 SHA512 ad9c927f9b4311921de6c59706c84872a7d3955dbea393c11179504a730a1495981b473483e44ea204b003e6b8fd11b7bb6198c642b79191d39d04dc2878147d
+DIST gentoo-kernel-5.4.106-2.arm64.xpak 56398328 BLAKE2B 7e35845e10b6e299e951886ea8821afc700d89cbfa0552e28a50b0078c3a44750246b8c77f0ca409f7162a200ad7110eefe3853754f23a54506945194ea9806e SHA512 c45278caa7e4e6212643ea87029c7a60522308d65547be87276eb391af0890dc602c7c4c34f17406679b6763a3d38bdfde1e7d90f7daabb03d3316f773645a1d
 DIST gentoo-kernel-5.4.94-1.amd64.xpak 61075025 BLAKE2B 96f7d69735dacd618266d4220907d2e196d4a59f39fdb6c93e88299ecd26a503684bcfbe0a0dcc8c027c3e1b90fc7c066f0d0cb5e007efee859215c6a4b91807 SHA512 e786c30e4ac3e62f25cb6403105847c20b7673f0e9fee32f513854c6e739cce513409f136da9dfd8c366d74ffc4db00625dc5d6270623af56149e4dd05801c57
 DIST gentoo-kernel-5.4.94-1.arm64.xpak 56309818 BLAKE2B 50f9f4d7bfaee560860899a0a16805c0a805a9cd0b915a0dec3f654180db73cc73f3247ccc808842103fefabe9cbc0aa963aff8c649c0fe2d314a6ddf22a02ce SHA512 36ee8c73e76ac00ea6c26a5530d6dab91df46fcf2b5f072bbcc44d8bf8b7df710fa601584ee2707cb1c1bbfad9342e369a00926224a0527f1fd4588d01085508
 DIST gentoo-kernel-5.4.94-1.x86.xpak 52893412 BLAKE2B b694d25318a84dd4d458b3ad42193781a42853fef9bc21c7e0f3671b5d74b9358c3408bb478d669d57f3618bc433d29df02bed71d80abc7bb8e8814c6e08997d SHA512 c64d72334079b3650c37427ab38e72d9b0d946d93989a491224a936e59d4eb0e43046bf03d85487d41ae6dec43cf5c5dd8667d3e2c9cf7355ec9e95f61f096e2

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.106-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.106-r1.ebuild
new file mode 100644
index 00000000000..999ceea0101
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.106-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-2
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${PV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"usr/src/linux-${PV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${PV}"/ || die
+}