[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

["Sam James" <sam@gentoo.org>]

commit:     b77e19b7464189274e5538c864baad932b8f9c2e
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  6 18:53:39 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Mar  6 18:53:57 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b77e19b7

sys-kernel/gentoo-kernel-bin: bump 5.11.3 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.11.3-r3.ebuild             | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index f8bf35143d2..3085b040d8f 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -26,6 +26,7 @@ DIST gentoo-kernel-5.11.2-1.amd64.xpak 64830406 BLAKE2B f9c5d0591a175e497e3ff9f9
 DIST gentoo-kernel-5.11.2-1.arm64.xpak 59866719 BLAKE2B 5c8e59242ac3512488afbc1335845294f6ed6b5f7cf0674c4655689b4e93284b110295da479c14f3bd70111c5f652a2c7c641bd34b06f9d7b21bacdb3965b746 SHA512 978891967b1b2c59ca1d4e77bd7d622585532e39cdaceae087a72c6f72d57764cd9dcdcad918ddb1c2d92a42ddc9859baf532971a280cbbe7c4811acb7cc3f5c
 DIST gentoo-kernel-5.11.2-1.x86.xpak 57784553 BLAKE2B 452b7e2bca5f9c83345b14f8a3e9ca54bd18e2b6f89e9d165ee3b59de8b8cd46411858a08d58546cde72180bf78c596f1ab3d595c2e5e818e2df9722101cf0b2 SHA512 9620e721c8c0e474db8861400b3109a2b26af68aafbe94975030a45f620e7f7ca5f9837d8dedfca6e97d5b4cf458ba76d34eee790268ddbcc4677d2b06e220df
 DIST gentoo-kernel-5.11.3-1.amd64.xpak 64831800 BLAKE2B ccc7ddf11246fe988720754eedfbfd336621918f975b2d952bea99180823361bdebade271f55b764d83df6461116dfa3e8008dc4920a77f1845fab177c3eb81b SHA512 278a8a7a817abaf09c8deb1ee6f42711ac497ded29596f55d29669a67e8b0ac0f95ff2af356cbce42880f328af1b6eb9b1ee787927820df4065a81c67787cadc
+DIST gentoo-kernel-5.11.3-1.arm64.xpak 59778759 BLAKE2B 350fcd7e21b5884f3b0fb0fb35c1df2147f4151182bdcf01c491dc4c89b09d2e75e8433c658dd649d9f9ccdecb4dfd47c912fd2b93d0ca9ca884d8bfe863518f SHA512 ff91a4278c2d14b4313a1a6bffc2480c0afa1671564d341df4572236d4e9e82ff03dc7fb32324252190c26fa07958cac20a8d965de38b438c04281e7b0ca915b
 DIST gentoo-kernel-5.11.3-1.x86.xpak 57808390 BLAKE2B c8fa0b6c4736face65fad6d3caa83311eb1457a1bedb65401c073d800c90634298e929b4acf6e2212dd3b2f863dc06b28ad67992ca1c81b21531bf335ca21e1b SHA512 2f5aa0e7595120c8bf0b552c88a22b2ddf2d2a0028c8e2154250b07d526d66becf6e459fae64b67f69f1c91f7afc1109e7c13b72b2f48aca1a3b36ec6ce18fae
 DIST gentoo-kernel-5.4.100-1.amd64.xpak 61080710 BLAKE2B 84b33a1aa252b0957eb90ddd792f001942589d7f65399a5b007a2c831d0a1fa3b879814a55e5cf8b1ad6166970d3ac89838f57a2c61cec6b7b136b55d5ea4c7b SHA512 98b3dfd31a2830ed49dfc7094e9f37a39e7fbef54b648b4840122f2b53b8e970fb9c75a653445753d8e4efbd723716b9c56b2f99214c79832f3e49de63b3efbe
 DIST gentoo-kernel-5.4.100-1.arm64.xpak 56394488 BLAKE2B b8ea7a56a087e98706099cc151b652dba2a40e2a39ae99670b0989ce2f11c133f07b53dda1a9749f946719ab8a5b97a57ee0a12fcf3d9a568b498859420eeef5 SHA512 549ada0acf8874d3254c8a586f5c4d0ed4f08a103aee74befae38fc47d10c716d86f3f133b8ee3c49e61fcacda2298b04b5fe96bf35917b0963f922fe424e96f

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.3-r3.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.3-r3.ebuild
new file mode 100644
index 00000000000..1d8f27f2627
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.3-r3.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${PV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"usr/src/linux-${PV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${PV}"/ || die
+}